1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# SPDX-License-Identifier: CC0-1.0
qt5 = import('qt5')
qt5_dep = dependency('qt5',
method : 'pkg-config',
modules : ['Core', 'Gui', 'Widgets'],
required : get_option('qcam'),
version : '>=5.4')
if not qt5_dep.found()
qcam_enabled = false
subdir_done()
endif
qcam_enabled = true
qcam_sources = files([
'cam_select_dialog.cpp',
'format_converter.cpp',
'main.cpp',
'main_window.cpp',
'message_handler.cpp',
'viewfinder_qt.cpp',
])
qcam_moc_headers = files([
'cam_select_dialog.h',
'main_window.h',
'viewfinder_qt.h',
])
qcam_resources = files([
'assets/feathericons/feathericons.qrc',
])
qt5_cpp_args = [apps_cpp_args, '-DQT_NO_KEYWORDS']
if cxx.has_header_symbol('QOpenGLWidget', 'QOpenGLWidget',
dependencies : qt5_dep, args : '-fPIC')
qcam_sources += files([
'viewfinder_gl.cpp',
])
qcam_moc_headers += files([
'viewfinder_gl.h',
])
qcam_resources += files([
'assets/shader/shaders.qrc'
])
endif
# gcc 9 introduced a deprecated-copy warning that is triggered by Qt until
# Qt 5.13. clang 10 introduced the same warning, but detects more issues
# that are not fixed in Qt yet. Disable the warning manually in both cases.
if ((cc.get_id() == 'gcc' and cc.version().version_compare('>=9.0') and
qt5_dep.version().version_compare('<5.13')) or
(cc.get_id() == 'clang' and cc.version().version_compare('>=10.0')))
qt5_cpp_args += ['-Wno-deprecated-copy']
endif
resources = qt5.preprocess(moc_headers : qcam_moc_headers,
qresources : qcam_resources,
dependencies : qt5_dep)
qcam = executable('qcam', qcam_sources, resources,
install : true,
install_tag : 'bin',
link_with : apps_lib,
dependencies : [
libatomic,
libcamera_public,
libtiff,
qt5_dep,
],
cpp_args : qt5_cpp_args)
|
