1 files changed, 37 insertions, 0 deletions
diff --git a/src/apps/lc-compliance/meson.build b/src/apps/lc-compliance/meson.build
new file mode 100644
index 00000000..b1f605f3
--- /dev/null
+++ b/src/apps/lc-compliance/meson.build
@@ -0,0 +1,37 @@
+# SPDX-License-Identifier: CC0-1.0
+
+libgtest = dependency('gtest', version : '>=1.10.0',
+                      required : get_option('lc-compliance'),
+                      fallback : ['gtest', 'gtest_dep'])
+
+if opt_lc_compliance.disabled() or not libevent.found() or not libgtest.found()
+    lc_compliance_enabled = false
+    subdir_done()
+endif
+
+lc_compliance_enabled = true
+
+lc_compliance_sources = files([
+    'environment.cpp',
+    'helpers/capture.cpp',
+    'main.cpp',
+    'tests/capture_test.cpp',
+])
+
+lc_compliance_includes = ([
+    include_directories('.'),
+    include_directories('helpers/')
+])
+
+lc_compliance  = executable('lc-compliance', lc_compliance_sources,
+                            cpp_args : [ '-fexceptions' ],
+                            link_with : apps_lib,
+                            dependencies : [
+                                libatomic,
+                                libcamera_public,
+                                libevent,
+                                libgtest,
+                            ],
+                            include_directories : lc_compliance_includes,
+                            install : true,
+                            install_tag : 'bin-devel')