1 files changed, 49 insertions, 0 deletions
diff --git a/src/libcamera/base/meson.build b/src/libcamera/base/meson.build
new file mode 100644
index 00000000..87172157
--- /dev/null
+++ b/src/libcamera/base/meson.build
@@ -0,0 +1,49 @@
+# SPDX-License-Identifier: CC0-1.0
+
+libcamera_base_sources = files([
+    'class.cpp',
+    'bound_method.cpp',
+    'event_dispatcher.cpp',
+    'event_dispatcher_poll.cpp',
+    'event_notifier.cpp',
+    'file.cpp',
+    'log.cpp',
+    'message.cpp',
+    'object.cpp',
+    'semaphore.cpp',
+    'signal.cpp',
+    'thread.cpp',
+    'timer.cpp',
+    'utils.cpp',
+])
+
+libcamera_base_deps = [
+    dependency('threads'),
+]
+
+# Internal components must use the libcamera_base_private dependency to enable
+# the use of headers which must not be exposed to the libcamera public api.
+libcamera_base_args = [ '-DLIBCAMERA_BASE_PRIVATE' ]
+
+libcamera_base_lib = shared_library('libcamera-base',
+                                    [libcamera_base_sources, libcamera_base_headers],
+                                    name_prefix : '',
+                                    install : true,
+                                    cpp_args : libcamera_base_args,
+                                    include_directories : libcamera_includes,
+                                    dependencies : libcamera_base_deps)
+
+libcamera_base = declare_dependency(sources : [
+                                        libcamera_base_headers,
+                                    ],
+                                    include_directories : libcamera_includes,
+                                    link_with : libcamera_base_lib)
+
+pkg_mod = import('pkgconfig')
+pkg_mod.generate(libcamera_base_lib,
+                 version : '1.0',
+                 description : 'Camera support base utility library',
+                 subdirs : 'libcamera')
+
+libcamera_base_private = declare_dependency(dependencies : libcamera_base,
+                                            compile_args : libcamera_base_args)